#!ipxe
### RogueScholar Custom Netboot.xyz iPXE Menu
###
### <https://github.com/RogueScholar/netboot.xyz-custom>
# I'd dress up my menu more, but Netboot.xyz doesn't have the console command.
# console --x 1280 --y 800
# console --picture http://boot.ipxe.org/texture.png --left 240 --right 240 --top 80 --bottom 120 --depth 24

:start
echo Greetings, wayfaring stranger.
:custom
clear custom_choice
menu Select the desired boot environment
item --gap Parted Magic (v2026_06_04)
item pmagic    ${space} x86_64 bzImage/initrd
item pmagiciso ${space} x86_64 ISO
item --gap Other utilities
item grmliso   ${space} Grml 2018.12 amd64 Full ISO
item grmlram   ${space} Grml 2018.12 amd64 Full ramdisk
item czillaiso ${space} Clonezilla Live 20191009 amd64 Ubuntu Eoan ISO
item czillaram ${space} Clonezilla Live 20191009 amd64 Ubuntu Eoan ramdisk
choose custom_choice || goto custom_exit
echo ${cls}
goto ${custom_choice}
goto custom_exit

:pmagic
set pmagic-path https://petermello.net/ipxe/pmagic
imgfetch --name bzImage ${pmagic-path}/bzImage
imgfetch --name initrd.img ${pmagic-path}/initrd.img
imgfetch --name PMAGIC_2026_06_04.SQFS ${pmagic-path}/pmodules/PMAGIC_2026_06_04.SQFS
chain bzImage initrd=initrd.img initrd=fu.img initrd=m32.img initrd=files.cgz boot=live ip=dhcp edd=on load_ramdisk=1 prompt_ramdisk=0 vga=normal sleep=0 loglevel=0 keymap=us rw splash nox2apic || goto custom_exit

:pmagiciso
set pmagic-path https://rscholar.keybase.pub/ipxe/pmagic
imgfetch --name memdisk ${pmagic-path}/memdisk?dl=1
imgfetch --name pmagic_2019_11_04.iso ${pmagic-path}/pmagic_2019_11_04.iso?dl=1
kernel memdisk initrd=pmagic_2019_11_04.iso iso vmalloc=256M
boot || goto custom_exit

:grmliso
set grml-path https://rscholar.keybase.pub/ipxe/grml
imgfetch --name memdisk ${grml-path}/memdisk?dl=1
imgfetch --name grml64-full_2018.12.iso ${grml-path}/grml64-full_2018.12.iso?dl=1
kernel memdisk initrd=grml64-full_2018.12.iso iso vmalloc=256M
boot || goto custom_exit

:grmlram
set grml-path https://rscholar.keybase.pub/ipxe/grml
imgfetch --name vmlinuz ${grml-path}/vmlinuz?dl=1
imgfetch --name initrd.img ${grml-path}/initrd.img?dl=1
imgfetch --name grml64-full.squashfs ${grml-path}/grml64-full.squashfs
chain vmlinuz initrd=initrd.img initrd=grml64-full.squashfs boot=live apm=power-off vga=791 nomce noeject noprompt noblank keyboard=us xkeyboard=us tz=America/Los_Angeles hostname ssh=password nox2apic || goto custom_exit

:czillaiso
set czilla-path https://rscholar.keybase.pub/ipxe/czilla
imgfetch --name memdisk ${czilla-path}/memdisk?dl=1
imgfetch --name clonezilla-live-20191009-eoan-amd64.iso ${czilla-path}/clonezilla-live-20191009-eoan-amd64.iso?dl=1
kernel memdisk initrd=clonezilla-live-20191009-eoan-amd64.iso iso vmalloc=256M
boot || goto custom_exit

:czillaram
set czilla-path https://rscholar.keybase.pub/ipxe/czilla
imgfetch --name vmlinuz ${czilla-path}/vmlinuz?dl=1
imgfetch --name initrd.img ${czilla-path}/initrd.img?dl=1
imgfetch --name filesystem.squashfs ${czilla-path}/filesystem.squashfs
chain vmlinuz initrd=initrd.img initrd=filesystem.squashfs boot=live username=user union=overlay config components quiet noswap edd=on nodmraid locales=en_US.UTF-8 ocs_live_run="ocs-live-general" ocs_live_batch=no net.ifnames=0 nosplash noprompt nox2apic || goto custom_exit

sleep 300
goto custom_exit

:custom_exit
exit 0

#chain https://raw.githubusercontent.com/RogueScholar/netboot.xyz-custom/master/custom1.ipxe || goto custom